1.概述

　　本文介紹無雙字功能的CPU如何實現(xiàn)類似雙字乘除運(yùn)算的方法.

　　Twido CPU中僅TWDLC*A10DRF無雙字功能,雖然應(yīng)用該型號CPU一般都是純邏輯控制,沒有高精度乘除運(yùn)算的需求,但有時用到高速計數(shù).電位器.操作終端輸入等情況,需要運(yùn)算來判斷位置或設(shè)定值參與運(yùn)算時則很不方便.

　　主要問題有:

　　1.)運(yùn)算時可能要改比例

　　2.)系統(tǒng)控制精度降低

　　2 具體描述

　　1.) 運(yùn)算時可能要改比例,因為有可能發(fā)生溢出錯誤.

　　下圖為Twido字對象格式:

　　從圖中可看到10進(jìn)制整數(shù)介于 -32768 和 32767 ,如果應(yīng)用中有10進(jìn)制運(yùn)算328*100時就發(fā)生溢出,結(jié)果不是預(yù)期中的32800,而是-32;

　　要想避免計算出錯,防止溢出,就必須使乘積結(jié)果小于32767,也就要改變乘數(shù)或被乘數(shù)的比例,如將328*100改為328*10=3280,這樣改后雖然不會出錯,但可能帶來了我們前面提到的第2.)個問題;

　　2.)系統(tǒng)控制精度降低

　　假設(shè)上述舉例為位置控制,328表示高速計數(shù)輸入,100表示單位脈沖長度輸入范圍,即可從0到100,如果這時單位脈沖長度為0.1毫米,那么當(dāng)范圍由0到100改為0到10時,單位脈沖長度相當(dāng)于1毫米了,這種只有舍棄精度才能保證正確的乘法運(yùn)算是我們不愿見到的;

　　再假設(shè)上述舉例中的高速計數(shù)輸入值大到20000,則根本無法乘運(yùn)算了,因此有必要擴(kuò)展乘除運(yùn)算功能;

　　3 單字乘除擴(kuò)展功能的實現(xiàn)

　　根據(jù)乘法原理:乘法表示相同的幾個數(shù)相加;即3*2=2+2+2, 相當(dāng)于3個2相加,因此可把積(結(jié)果)=被乘數(shù)*乘數(shù)相當(dāng)于=被乘數(shù)+…+被乘數(shù),共乘數(shù)個被乘數(shù)相加,但這樣做當(dāng)乘數(shù)很大時算會很麻煩,如乘數(shù)為1234時被乘數(shù)加1234次才有結(jié)果, 程序量大不易實現(xiàn);

　　根據(jù)10進(jìn)制數(shù)定義, 1234=1*1000+2*100+3*10+4*1,這樣拆解乘數(shù)以后用1,2,3,4分別乘以乘數(shù)再累加求和,將大于32767的累加值的進(jìn)位放到高字,小于32767的放在低字存儲,用連續(xù)的兩個高低字實現(xiàn),這樣運(yùn)算程序容易編且執(zhí)行速度快.

　　詳細(xì)說明可參考以下程序:

　　程序要求:被乘數(shù)與乘數(shù)，其中一個不能大于3640(因3640*9<32767)，另外一個不能大于32767(因為單字定義不能大于32767)，否則結(jié)果無意義

　　乘積范圍：(0 到3640)*32767=119271880

　　除法是乘法的反過程不作詳細(xì)說明,除數(shù)要求<=3640;

　　程序(TXT類型,可在下拉菜單選:程序à導(dǎo)入àASCII程序,打開梯形圖)

　　(* %MW300,%MW301是乘數(shù)、被乘數(shù)(范圍：0 - 3640*32767=119271880)，其中一個〈3640 *)

　　(* %MW333是除數(shù)《=3640 *****下面還有說明***** *)

　　(* %MW320，MW321是乘法擴(kuò)展低、高位 *)

　　(* %MW340，MW341是除法擴(kuò)展低、高位 *)

　　LD 1

　　SR0

　　END

　　(* 乘法擴(kuò)展子程序(范圍：0 - 3640*32767=119271880) *)

　　(* (算法要求：被乘數(shù)與乘數(shù)，其中一個不能大于3640，另外一個不能大于32767，否則結(jié)果無意義) *)

　　SR0:

　　LD 1

　　[ %MW320 := 0 ]

　　[ %MW321 := 0 ]

　　[ %MW322 := 0 ]

　　[ %MW323 := 0 ]

(* 乘法計算初步分析 *)

　　(* %MW300被乘數(shù) %MW301乘數(shù) %MW302臨時寄存器 *)

　　LD 1

　　[ %MW302 := %MW300 * %MW301 ]

　　(* 沒有溢出，則處理高低位后，直接輸出 *)

　　LDN %S18

　　JMPC %L0

　　(* 結(jié)果溢出，則復(fù)位溢出寄存器 *)

　　LD %S18

　　R %S18

　　(* 比較被乘數(shù)與乘數(shù)，被乘數(shù)要求：小于等于乘數(shù)，不能大于3640 *)

　　LD [ %MW300 <= %MW301 ]

　　JMPC %L1

　　(* 被乘數(shù)大于乘數(shù)，則交換被乘數(shù)與乘數(shù) *)

　　LD 1

　　[ %MW302 := %MW300 ]

　　[ %MW300 := %MW301 ]

　　[ %MW301 := %MW302 ]

　　%L1:

　　LD 1

　　[ %MW303 := %MW301 ]

　　(* 計算乘數(shù)個位與被乘數(shù)的積 *)

　　LD 1

　　[ %MW304 := %MW303 REM 10 ]

　　[ %MW313 := %MW304 * %MW300 ]

　　[ %MW305 := %MW303 / 10 ]

　　LD [ %MW305 = 0 ]

　　JMPC %L2

　　(* 計算乘數(shù)十位與被乘數(shù)的積 *)

　　LD 1

　　[ %MW306 := %MW305 REM 10 ]

　　[ %MW314 := %MW306 * %MW300 ]

　　[ %MW307 := %MW305 / 10 ]

　　LD [ %MW307 = 0 ]

　　JMPC %L3

　　(* 計算乘數(shù)百位與被乘數(shù)的積 *)

　　LD 1

　　[ %MW308 := %MW307 REM 10 ]

　　[ %MW315 := %MW308 * %MW300 ]

　　[ %MW309 := %MW307 / 10 ]

　　LD [ %MW309 = 0 ]

　　JMPC %L4

　　(* 計算乘數(shù)千位與被乘數(shù)的積 *)

　　LD 1

　　[ %MW310 := %MW309 REM 10 ]

　　[ %MW316 := %MW310 * %MW300 ]

　　[ %MW311 := %MW309 / 10 ]

　　LD [ %MW311 = 0 ]

　　JMPC %L5

　　(* 計算乘數(shù)的萬位與被乘數(shù)的積之和 *)

　　LD 1

　　[ %MW312 := %MW311 REM 10 ]

　　[ %MW317 := %MW312 * %MW300 ]

　　[ %MW318 := 0 ]

　　[ %MW319 := %MW317 ]

　　[ %MW320 := %MW320 + %MW318 ]

　　[ %MW321 := %MW321 + %MW319 ]

　　(* 計算乘數(shù)的萬、千位與被乘數(shù)的積之和 *)

　　%L5:

　　LD 1

　　[ %MW318 := %MW316 REM 10 ]

　　[ %MW318 := %MW318 * 1000 ]

　　[ %MW319 := %MW316 / 10 ]

　　[ %MW320 := %MW320 + %MW318 ]

　　[ %MW321 := %MW321 + %MW319 ]

　　(* 計算乘數(shù)的萬、千、百位與被乘數(shù)的積之和 *)

　　%L4:

　　LD 1

　　[ %MW318 := %MW315 REM 100 ]

[ %MW318 := %MW318 * 100 ]

　　[ %MW319 := %MW315 / 100 ]

　　[ %MW320 := %MW320 + %MW318 ]

　　[ %MW321 := %MW321 + %MW319 ]

　　(* 計算乘數(shù)的萬、千、百、十位與被乘數(shù)的積之和 *)

　　%L3:

　　LD 1

　　[ %MW318 := %MW314 REM 1000 ]

　　[ %MW318 := %MW318 * 10 ]

　　[ %MW319 := %MW314 / 1000 ]

　　[ %MW320 := %MW320 + %MW318 ]

　　[ %MW321 := %MW321 + %MW319 ]

　　(* 計算乘數(shù)的萬、千、百、十、個位與被乘數(shù)的積之和 *)

　　%L2:

　　LD 1

　　[ %MW318 := %MW313 REM 10000 ]

　　[ %MW319 := %MW313 / 10000 ]

　　[ %MW320 := %MW320 + %MW318 ]

　　[ %MW302 := %MW320 ]

　　[ %MW320 := %MW302 REM 10000 ]

　　[ %MW302 := %MW302 / 10000 ]

　　(* 計算最終結(jié)果 *)

　　LD 1

　　[ %MW321 := %MW321 + %MW302 ]

　　[ %MW321 := %MW321 + %MW319 ]

　　JMPC %L6

　　(* 高低位處理直接計算結(jié)果 *)

　　%L0:

　　LD 1

　　[ %MW320 := %MW302 REM 10000 ]

　　[ %MW321 := %MW302 / 10000 ]

　　(* 最終計算結(jié)果輸出 *)

　　%L6:

　　LD 1

　　[ %MW322 := %MW320 ]

　　[ %MW323 := %MW321 ]

　　(* 高位除法得到高位商值，余數(shù)，%MW333為除數(shù)必須小于3640 *)

　　(* 否則結(jié)果錯誤 *)

　　LD 1

　　[ %MW341 := %MW321 / %MW333 ]

　　[ %MW342 := %MW321 REM %MW333 ]

　　(* 高位余數(shù)加低位千位數(shù)除 *)

　　LD 1

　　[ %MW332 := %MW320 / 1000 ]

　　[ %MW331 := %MW320 REM 1000 ]

　　[ %MW343 := %MW342 * 10 ]

　　[ %MW344 := %MW343 + %MW332 ]

　　[ %MW345 := %MW344 / %MW333 ]

　　[ %MW346 := %MW344 REM %MW333 ]

　　(* 千位除法余數(shù)加百位數(shù)除 *)

　　LD 1

　　[ %MW347 := %MW331 / 100 ]

　　[ %MW348 := %MW331 REM 100 ]

　　[ %MW349 := %MW346 * 10 ]

　　[ %MW350 := %MW349 + %MW347 ]

　　[ %MW351 := %MW350 / %MW333 ]

　　[ %MW352 := %MW350 REM %MW333 ]

　　(* 百位除法余數(shù)加十位數(shù)除 *)

　　LD 1

　　[ %MW353 := %MW348 / 10 ]

　　[ %MW354 := %MW348 REM 10 ]

[ %MW355 := %MW352 * 10 ]

　　[ %MW356 := %MW355 + %MW353 ]

　　[ %MW357 := %MW356 / %MW333 ]

　　[ %MW358 := %MW356 REM %MW333 ]

　　(* 十位除法余數(shù)加個位數(shù)除 *)

　　LD 1

　　[ %MW359 := %MW358 * 10 ]

　　[ %MW360 := %MW359 + %MW354 ]

　　[ %MW361 := %MW360 / %MW333 ]

　　[ %MW362 := %MW360 REM %MW333 ]

　　(* 千、百、十、個位商值求和 *)

　　LD 1

　　[ %MW363 := %MW345 * 1000 ]

　　[ %MW364 := %MW351 * 100 ]

　　[ %MW365 := %MW357 * 10 ]

　　[ %MW366 := %MW363 + %MW364 ]

　　[ %MW367 := %MW365 + %MW361 ]

　　[ %MW340 := %MW366 + %MW367 ]

　　(* 個位余數(shù)如果大于除數(shù)一半，即四舍五入到商數(shù)低位%MW340 *)

　　LD 1

　　[ %MW368 := %MW333 / 2 ]

　　AND [ %MW362 >= %MW368 ]

　　[ %MW340 := %MW340 + 1 ]

　　RET